Sans FinePrint (http://www.fineprint.com/) il faut utiliser la fonction *Zoom* de la boîte d'impression réglée sur 2 pages par feuille en sélectionnant bien chaque couple de pages à imprimer.

Pour pouvoir rétablir l'ordre très particulier des pages recto-verso, voici un petite macro qui recalcule le tout dans l'ordre ; ça dépend un peu de l'imprimante selon qu'elle imprime par dessus ou par dessous (pour garder la pile dans le bon sens à la 2ème passe)

Ajouter au besoin des pages blanches pour que le total des pages soit un multiple de 4.

Public Sub ImprimeEnLivret()
' macro écrite par Anacoluthe
' imprime le document sous forme de livret
' pour imprimante imprimant les pages dans l'ordre inverse
' imprimante inverse : l'ordre des pages de la pile finale est inversé
' utilise les fonctions zoom de l'impression WORD
Dim NbPages, NbFeuilles, i, Rep As Integer
Dim CouplePage As String
NbPages = ActiveDocument.BuiltInDocumentProperties(wdPropertyPages)
NbFeuilles = Int((NbPages + 3) / 4)
If NbFeuilles * 4 = NbPages Then
Rep = MsgBox("Impression recto-verso de " & _
NbFeuilles & " pages ?", vbYesNo, "Livret")
If Rep = vbYes Then
' impression des rectos
For i = 0 To NbFeuilles - 1
CouplePage = Str((4 * NbFeuilles) - (2 * i)) & ";" & Str(2 * i + 1)
Impr2pages (CouplePage)
Next i
Rep = MsgBox(" retourner les feuilles et appuyer sur OK", vbOKOnly)
' impression des versos
For i = 0 To NbFeuilles - 1
CouplePage = Str(2 * i + 2) & ";" & Str((4 * NbFeuilles) - (2 * i) - 1)
Impr2pages (CouplePage)
Next i
End If
Else
MsgBox " Je n'imprime qu'un multiple de 4 pages !", vbCritical
End If
End Sub


Sub Impr2pages(MesPages As String)
' fonction imprime deux pages utilisée par ImprimeEnLivret
' à adapter selon son format de papier
' d'après simple macro enregistrée d'une impression d'essai
Application.PrintOut FileName:="", Range:=wdPrintRangeOfPages, _
Item:=wdPrintDocumentContent, Copies:=1, Pages:=MesPages, PageType:= wdPrintAllPages, _
Collate:=True, Background:=False, PrintToFile:=False, PrintZoomColumn:=2, PrintZoomRow:=1, _
PrintZoomPaperWidth:=11907, PrintZoomPaperHeight:=16839

End Sub